I have a second partition set up on my CFCard, so in turn I have a win2_ drive. I created a directory on here called "Beano" and copied the game files into it.
To get the game to run, you need to use a substitution utility to fool the game into thinking it is running from a floppy disk. I found the usual DEV_USE tricks didn't work, in particular the DEV_USE flp didn't work on the Tetroid. What does work is the "SUB" device driver which can be found on Dilwyn's site http://www.dilwyn.me.uk/tk/sub.zip. So, I copied the sub_rext into the win1_SYS folder and added "LRESPR sys$&'sub_rext'" to my main boot file.
Then I edited the boot file in the win2_BEANO_ directory and added these lines...
Code: Select all
10 SUB_DRV win2
20 SUB_USE 1,BEANO
30 SUB_USE FLP
At this point if you do an "LRUN win2_beano_boot" the game runs and thinks it is running from its default configuration of flp1_.
My main boot file...
Code: Select all
100 WIN_DRIVE 2,1,2
110 LET dev$='win1_'
120 LET sys$=dev$&'SYS_'
130 addr=RESPR(250) : LBYTES sys$&'exists_bin',addr : CALL addr
140 :
150 IF NOT(EXISTS('TK2_EXT')) THEN
160 addr=RESPR(16876) : LBYTES sys$&'tk226_bin',addr : CALL addr
170 END IF
180 TK2_EXT
190 :
200 base=RESPR(3000) : LBYTES sys$&'vtkql_bin',base : CALL base
240 :
260 LRESPR sys$&'sub_rext'
540 LRESPR sys$&'history_cde'
550 HISTORY #0, 20
560 :
570 NEW
Code: Select all
[10 SUB_DRV win2
20 SUB_USE 1,BEANO
30 SUB_USE FLP
100 REMark BOOT FOR THE VOYAGE OF THE BEANO
110 REMark (C) 1990 A. PEMBERTON
120 RESTORE
130 MODE 4:OPEN#3,scr:WINDOW#3,512,256,0,0:PAPER#3,0:CLS#3
140 FOR r=1 TO 23:OPEN#(r+3),scr:WINDOW#(r+3),20,40,(r*20+20),0:PAPER#(r+3),0:INK#(r+3),7
150 x$="THE VOYAGE OF THE BEANO"
160 FOR r=1 TO 23:AT#(r+3),3,0:PRINT#(r+3),x$(r):BEEP 1000,r*RND(10 TO 50):PAUSE 3
170 a=RESPR(512):LBYTES flp1_font_cde,a:CALL a
180 LBYTES flp1_p0,131072+60*128:credits
185 play
190 FOR x=4 TO 9:wave -1,x,5:PAUSE 3
200 FOR x=4 TO 16:wave 1,x,5:wave -1,x+6,5
210 FOR x=17 TO 21:wave 1,x,5:wave -1,x+6,21-x
220 FOR x=22 TO 27:wave 1,x,27-x:PAUSE 3
230 INK#3,7:AT#3,24,27:PRINT#3,"PRESS ANY KEY TO GET UNDER WAY....":dummy$=INKEY$(-1):AT#3,24,15:CLS#3,4
240 EXEC_W flp1_BEANO_obj
250 :
260 DEFine PROCedure wave (direction,start,number)
270 FOR r=1 TO number
280 SCROLL#(start-1+r),direction*(6-r)
290 END FOR r
300 END DEFine wave
310 DEFine PROCedure credits
320 AT#3,21,0:INK#3,4:PRINT#3,,,"A GRAPHIC ADVENTURE BY ALAN PEMBERTON AND FRANCIS O'BRIEN"\,,," COPYRIGHT 1990 C G H SERVICES"
330 END DEFine credits
340 DEFine PROCedure play
350 LOCal note$,dur,del,x,loop
355 REPeat loop
360 IF BEEPING:NEXT loop
370 IF EOF:EXIT loop
380 READ note$,dur,del
390 IF dur=0:RETurn
400 x=CODE(note$)
410 SELect ON x
420 =97:n=42
430 =98:n=37
440 =99:n=35
450 =100:n=70
460 =101:n=61
470 =102:n=56
480 =103:n=50
490 =67:n=170
500 =65:n=96
510 END SELect
520 BEEP 1000*dur,n
530 PAUSE 4*del
535 END REPeat loop
540 END DEFine play
550 DATA 'c',1,1,'b',1,1,'c',2,2.25,'C',2.25,2.25,'C',2.25,2.25,'g',.75,.75,'f',.75,.75,'e',.75,.75,'g',.75,.75,'c',.75,.75,'b',1,1,'c',2,2,'x',0,0